cntr 2.0.0

A container debugging tool based on Linux mount API
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108

{
  description = "A container debugging tool based on FUSE";

  inputs = {
    nixpkgs.url = "git+https://github.com/NixOS/nixpkgs?shallow=1&ref=nixpkgs-unstable";
    flake-parts.url = "github:hercules-ci/flake-parts";
    flake-parts.inputs.nixpkgs-lib.follows = "nixpkgs";

    treefmt-nix.url = "github:numtide/treefmt-nix";
    treefmt-nix.inputs.nixpkgs.follows = "nixpkgs";

    fenix.url = "github:nix-community/fenix";
    fenix.inputs.nixpkgs.follows = "nixpkgs";
  };

  outputs =
    inputs@{ flake-parts, self, ... }:
    flake-parts.lib.mkFlake { inherit inputs; } {
      imports = [ ./treefmt.nix ];
      systems = [
        "x86_64-linux"
        "aarch64-linux"
        "riscv64-linux"
        "x86_64-darwin"
        "aarch64-darwin"
      ];
      perSystem =
        {
          pkgs,
          config,
          lib,
          ...
        }:
        {
          packages = lib.optionalAttrs (!pkgs.stdenv.isDarwin) {
            cntr = pkgs.callPackage ./default.nix {
              inherit self;
              inherit (pkgs) pkgsStatic;
            };
            default = config.packages.cntr;
          };
          devShells.default =
            if pkgs.stdenv.isDarwin then
              let
                crossPkgs = pkgs.pkgsCross.musl64;
                crossToolchain = crossPkgs.stdenv.cc;
                rustTargetTriple = "x86_64-unknown-linux-musl";
                rustToolchain = inputs.fenix.packages.${pkgs.system}.stable.withComponents [
                  "cargo"
                  "clippy"
                  "rust-src"
                  "rustc"
                ];
                rustToolchainWithTarget = inputs.fenix.packages.${pkgs.system}.combine [
                  rustToolchain
                  inputs.fenix.packages.${pkgs.system}.targets.${rustTargetTriple}.stable.rust-std
                ];
              in
              pkgs.mkShell {
                buildInputs = [
                  rustToolchainWithTarget
                  pkgs.rust-analyzer
                  crossToolchain
                ];
                CARGO_BUILD_TARGET = rustTargetTriple;
                CARGO_TARGET_X86_64_UNKNOWN_LINUX_MUSL_LINKER = "${crossToolchain}/bin/${crossPkgs.stdenv.cc.targetPrefix}cc";
              }
            else
              pkgs.mkShell {
                buildInputs = [
                  pkgs.cargo
                  pkgs.cargo-watch
                  pkgs.rustc
                  pkgs.clippy
                  pkgs.rust-analyzer
                ];
                CNTR_TEST_SHELL = "${pkgs.pkgsStatic.busybox}/bin/sh";
              };
          checks = lib.optionalAttrs (!pkgs.stdenv.isDarwin) (
            {
              clippy = (
                config.packages.cntr.override {
                  withClippy = true;
                }
              );
              shell-completions = pkgs.callPackage ./shell-completion-test.nix {
                inherit (config.packages) cntr;
              };
            }
            // lib.optionalAttrs (!pkgs.stdenv.hostPlatform.isRiscV64) {
              inherit
                (pkgs.callPackages ./vm-test.nix {
                  inherit (config.packages) cntr;
                })
                docker
                podman
                podman-rootless
                nspawn
                k3s
                builder
                apparmor
                ;
            }
            // lib.mapAttrs' (n: lib.nameValuePair "package-${n}") config.packages
          );
        };
    };
}