cntr 1.5.4

A container debugging tool based on FUSE
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64

{
  description = "A container debugging tool based on FUSE";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
    flake-parts.url = "github:hercules-ci/flake-parts";
    flake-parts.inputs.nixpkgs-lib.follows = "nixpkgs";

    treefmt-nix.url = "github:numtide/treefmt-nix";
    treefmt-nix.inputs.nixpkgs.follows = "nixpkgs";
  };

  outputs =
    inputs@{ flake-parts, self, ... }:
    flake-parts.lib.mkFlake { inherit inputs; } {
      imports = [ ./treefmt.nix ];
      systems = [
        "x86_64-linux"
        "aarch64-linux"
        "riscv64-linux"
      ];
      perSystem =
        {
          pkgs,
          config,
          lib,
          ...
        }:
        {
          packages.cntr = pkgs.callPackage ./default.nix {
            inherit self;
          };
          packages.default = config.packages.cntr;
          devShells.default = pkgs.mkShell {
            buildInputs = [
              pkgs.cargo
              pkgs.cargo-watch
              pkgs.rustc
              pkgs.clippy
              pkgs.cargo-bloat
              pkgs.rust-analyzer
            ];
          };
          checks =
            {
              clippy = (
                config.packages.cntr.override {
                  withClippy = true;
                }
              );
            }
            // lib.optionalAttrs (!pkgs.hostPlatform.isRiscV64) {
              inherit
                (pkgs.callPackages ./vm-test.nix {
                  inherit (config.packages) cntr;
                })
                docker
                podman
                ;
            }
            // lib.mapAttrs' (n: lib.nameValuePair "package-${n}") config.packages;
        };
    };
}