clickhouse-data-type 0.2.0

ClickHouse Data Types
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134

type_name = {
    UInt256 | UInt64 | UInt32 | UInt16 | UInt8 |
    Int256 | Int128 | Int64 | Int32 | Int16 | Int8 |
    Float32 | Float64 |
    Decimal |
    String |
    FixedString |
    UUID |
    DateTime64 | DateTime | Date |
    Enum16 | Enum8 |
    IPv4 | IPv6 |
    // 
    // 
    //
    LowCardinality |
    Nullable |
    Point | Ring | Polygon | MultiPolygon |
    // 
    // 
    // 
    Array |
    Tuple |
    Map
}


UInt8 = { "UInt8" }
UInt16 = { "UInt16" }
UInt32 = { "UInt32" }
UInt64 = { "UInt64" }
UInt256 = { "UInt256" }
Int8 = { "Int8" }
Int16 = { "Int16" }
Int32 = { "Int32" }
Int64 = { "Int64" }
Int128 = { "Int128" }
Int256 = { "Int256" }

Float32 = { "Float32" }
Float64 = { "Float64" }

Decimal = { "Decimal" ~ "(" ~ Decimal_precision ~ "," ~ Decimal_scale ~ ")" }
Decimal_precision = @{ ASCII_NONZERO_DIGIT{1, 2} }
Decimal_scale = @{ ASCII_DIGIT{1, 2} }

String = { "String" }

FixedString = { "FixedString" ~ "(" ~ FixedString_n ~ ")" }
FixedString_n = @{ ASCII_NONZERO_DIGIT+ }

UUID = { "UUID" }

Date = { "Date" }
DateTime = { "DateTime" ~ "(" ~ "'" ~ DateTime_timezone ~ "'" ~ ")" | "DateTime" }
DateTime64 = { "DateTime64" ~ "(" ~ DateTime64_precision ~ ("," ~ "'" ~ DateTime_timezone ~ "'" )? ~ ")" }
DateTime64_precision = @{ ASCII_DIGIT }
DateTime_timezone = @{ DateTime_timezone_char+ ~ "/" ~ DateTime_timezone_char+ | DateTime_timezone_char+ }
DateTime_timezone_char = @{ ASCII_ALPHA | "-" | "_" }

Enum8 = { "Enum8" ~ "(" ~ Enum_pair ~ ("," ~ Enum_pair)* ~ ")" }
Enum16 = { "Enum16" ~ "(" ~ Enum_pair ~ ("," ~ Enum_pair)* ~ ")" }
Enum_pair = { "'" ~ Enum_key ~ "'" ~ " "* ~ "=" ~ " "* ~ Enum_value }
Enum_key = @{ ASCII_ALPHANUMERIC+ }
Enum_value = @{ "-"? ~ ASCII_DIGIT+ }

IPv4 = { "IPv4" }

IPv6 = { "IPv6" }

LowCardinality = { "LowCardinality" ~ "(" ~ LowCardinality_data_type ~ ")" }
LowCardinality_data_type = {
    UInt64 | UInt32 | UInt16 | UInt8 |
    Int64 | Int32 | Int16 | Int8 |
    Float32 | Float64 |
    String |
    FixedString |
    DateTime | Date |
    Enum16 | Enum8 |
    IPv4 | IPv6 |
    // 
    // 
    // 
    Nullable
}

Nullable = { "Nullable" ~ "(" ~ Nullable_type_name ~ ")" }
Nullable_type_name = {
    Nullable_Nothing |
    UInt256 | UInt64 | UInt32 | UInt16 | UInt8 |
    Int256 | Int128 | Int64 | Int32 | Int16 | Int8 |
    Float32 | Float64 |
    Decimal |
    String |
    FixedString |
    UUID |
    DateTime64 | DateTime | Date |
    Enum16 | Enum8 |
    IPv4 | IPv6
}
Nullable_Nothing = { "Nothing" }

Array = { "Array" ~ "(" ~ type_name ~ ")" }

Tuple = { "Tuple" ~ "(" ~ type_name ~ ("," ~ type_name)* ~ ")" }

Map = { "Map" ~ "(" ~ Map_key ~ "," ~ Map_value ~ ")" }
Map_key = {
    UInt256 | UInt64 | UInt32 | UInt16 | UInt8 |
    Int256 | Int128 | Int64 | Int32 | Int16 | Int8 |
    Float32 | Float64 |
    Decimal |
    String |
    FixedString
}
Map_value = {
    UInt256 | UInt64 | UInt32 | UInt16 | UInt8 |
    Int256 | Int128 | Int64 | Int32 | Int16 | Int8 |
    Float32 | Float64 |
    Decimal |
    String |
    FixedString |
    // 
    // 
    // 
    Array
}

// geo
Point = { "Point" }
Ring = { "Ring" }
Polygon = { "Polygon" }
MultiPolygon = { "MultiPolygon" }

WHITESPACE = _{ " " }