cicd-mel 0.9.2

Mélodium CI/CD library
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90

use fs/file::read
use fs/file::write
use log/logger::Logger
use log/log::logErrors
use log/log::logError
use std/flow::one
use std/text/convert/string::fromUtf8
use std/text/compose::rescale
use std/text/compose::trimEnd
use work/resources::getFileSystem

treatment ioToString()
  input  stdio: Stream<byte>
  output lines: Stream<string>
{
    fromUtf8()
    rescale(delimiter="\n")
    trimEnd()

    Self.stdio -> fromUtf8.encoded,text -> rescale.unscaled,scaled -> trimEnd.text,trimmed -> Self.lines
}

treatment writeFile[logger: Logger](var label: string)
  input filesystem_name: Block<string>
  input file_path: Block<string>
  input data: Stream<byte>
  output finished: Block<void>
  output failed: Block<void>
  output completed: Block<void>
{
    getFileSystem()
    write()

    Self.filesystem_name -> getFileSystem.name,filesystem -> write.filesystem
    Self.file_path ----------------------------------------> write.path
    Self.data ---------------------------------------------> write.data

    logFsErr: logError[logger=logger](label=label)
    logWriteErrs: logErrors[logger=logger](label=label)
    getFileSystem.error -> logFsErr.message
    write.errors --------> logWriteErrs.messages

    oneFailed: one<void>()
    getFileSystem.failed -> oneFailed.a
    write.failed ---------> oneFailed.b

    oneFailedOrFinished: one<void>()
    oneFailed.value -> oneFailedOrFinished.a
    write.finished --> oneFailedOrFinished.b

    write.completed -----------> Self.completed
    oneFailed.value -----------> Self.failed
    oneFailedOrFinished.value -> Self.finished
}

treatment readFile[logger: Logger](var label: string)
  input filesystem_name: Block<string>
  input file_path: Block<string>
  output started: Block<void>
  output finished: Block<void>
  output failed: Block<void>
  output completed: Block<void>
  output data: Stream<byte>
{
    getFileSystem()
    read()

    Self.filesystem_name -> getFileSystem.name,filesystem -> read.filesystem
    Self.file_path ----------------------------------------> read.path

    logFsErr: logError[logger=logger](label=label)
    logReadErrs: logErrors[logger=logger](label=label)
    getFileSystem.error -> logFsErr.message
    read.errors ---------> logReadErrs.messages

    oneFailed: one<void>()
    getFileSystem.failed -> oneFailed.a
    read.failed ----------> oneFailed.b

    oneFailedOrFinished: one<void>()
    oneFailed.value -> oneFailedOrFinished.a
    read.finished ---> oneFailedOrFinished.b

    read.reached --------------> Self.started
    read.completed ------------> Self.completed
    oneFailed.value -----------> Self.failed
    oneFailedOrFinished.value -> Self.finished

    read.data -> Self.data
}