chrome-devtools 1.4.0

Profile-aware CLI for running Chrome DevTools MCP with isolated Chrome user data directories
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56

{
  lib,
  stdenvNoCC,
  fetchzip,
  makeWrapper,
  nodejs,
}:

stdenvNoCC.mkDerivation rec {
  pname = "chrome-devtools-mcp";
  version = "1.8.0";

  src = fetchzip {
    name = "${pname}-${version}.tgz";
    url = "https://registry.npmjs.org/${pname}/-/${pname}-${version}.tgz";
    extension = "tar.gz";
    hash = "sha256-5072DGsHCLYb50BMUgtjSn/1l8Ua538yPwdS3Ldkjmo=";
  };

  nativeBuildInputs = [ makeWrapper ];

  # Upstream leaves Puppeteer's protocolTimeout at 180 seconds. A shared Chrome
  # can exceed that while another session runs a heavy CDP command, so align the
  # default with the broker's 300-second heavy-tool timeout. The environment
  # variable remains available for callers that need a different value.
  postPatch = ''
    substituteInPlace build/src/browser.js \
      --replace-fail 'const connectOptions = {' \
        'const connectOptions = {
        protocolTimeout: Number(process.env.CHROME_DEVTOOLS_MCP_PROTOCOL_TIMEOUT_MS ?? 300000),'
  '';

  installPhase = ''
    runHook preInstall
    mkdir -p $out/lib/${pname}
    cp -r . $out/lib/${pname}
    makeWrapper ${nodejs}/bin/node $out/bin/${pname} \
      --add-flags $out/lib/${pname}/build/src/bin/chrome-devtools-mcp.js
    runHook postInstall
  '';

  doInstallCheck = true;
  installCheckPhase = ''
    runHook preInstallCheck
    $out/bin/${pname} --version | grep -F ${version}
    runHook postInstallCheck
  '';

  meta = {
    description = "MCP server exposing Chrome DevTools capabilities to AI coding assistants";
    homepage = "https://github.com/ChromeDevTools/chrome-devtools-mcp";
    license = lib.licenses.asl20;
    mainProgram = pname;
    platforms = lib.platforms.unix;
  };
}