calyx 0.7.1

Compiler Infrastructure for Hardware Accelerator Generation
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69

if exists("b:current_syntax")
  finish
endif

" Numbers
syn match futilConstant "\v<[0-9]+('(d|b|x|o)[0-9]+)?>"
hi link futilConstant  Constant

" String literals for attributes
syn region futilString start=/\v"/ skip=/\v\\./ end=/\v("|$)/
hi link futilString String

" @ style attributes
syn match futilAttr '\v\@[a-zA-Z_]+' nextgroup=futilAttrVal
syn region futilAttrVal start=/\v\(/ end=/\v\)/ contains=futilConstant,futilComment
hi link futilAttr String

" Control statements
syn keyword futilControl while if with seq par invoke else
hi link futilControl Special

" Other keywords
syn keyword futilKeyword import cells wires control group extern
hi link futilKeyword Keyword

" Primitive, component, and groups
syn keyword futilKeyword component group primitive nextgroup=futilBoundName skipwhite
syn match futilBoundName '\v[_a-zA-Z]((\-+)?[_a-zA-Z0-9]+)*' contained nextgroup=futilAttrs,futilParams,futilPorts
hi link futilBoundName Include

" Parameters attached to primitives
syn region futilParams start=/\v\[/  end=/\v\]/ contains=futilParam,futilComment nextgroup=futilPorts skipwhite skipnl
syn match futilParam '\v[_a-zA-Z]((\-+)?[_a-zA-Z0-9]+)*' contained
hi link futilParam Type

" Port definitions
syn region futilPorts start=/\v\(/  end=/\v\)/ contains=futilPortDef,futilAttr,futilComment contained
syn match futilPortDef '\v[_a-zA-Z]((\-+)?[_a-zA-Z0-9]+)*' contained nextgroup=futilDefColon skipwhite
syn match futilDefColon ':' contained nextgroup=futilPortParam skipwhite
syn match futilPortParam '\v([_a-zA-Z]((\-+)?[_a-zA-Z0-9]+)*)|([1-9][0-9]*)' contained
hi link futilPortParam Type

" Output ports come after the arrow
syn match futilArrow '->' nextgroup=futilPorts skipwhite skipnl
hi link futilArrow futilOperator

" Modifiers for components, groups, primitives
syn keyword futilModifier comb ref
hi link futilModifier Operator

" Highlight holes
syn keyword futilHole go done
hi link futilHole Type

" Delimiters
syn match futilOperator '!'
syn match futilOperator '!='
syn match futilOperator '='
syn match futilOperator '?'
syn match futilOperator '&'
syn match futilOperator '|'
hi link futilOperator Operator

" Comments
syntax match futilComment "\v//.*$"
syn region futilComment start=/\v\/\*/ skip=/\v\\./ end=/\v\*\//
hi link futilComment  Comment

let b:current_syntax = "futil"