burn_dragon_kernel 0.5.0

Fused GPU kernel crate for burn_dragon execution paths
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85

enable packed_4x8_integer_dot_product;

@group(0) @binding(0)
var<storage, read> input_codes: array<i32>;

@group(0) @binding(1)
var<storage, read> weight_codes: array<i32>;

@group(0) @binding(2)
var<storage, read_write> output_values: array<f32>;

@group(0) @binding(3)
var<storage, read> scale_values: array<f32>;

@group(0) @binding(4)
var<storage, read> meta_values: array<f32>;

fn meta_u(index: u32) -> u32 {
  return u32(meta_values[index]);
}

fn pack_i8x4(v0: i32, v1: i32, v2: i32, v3: i32) -> u32 {
  let b0 = bitcast<u32>(clamp(v0, -127, 127)) & 0xffu;
  let b1 = (bitcast<u32>(clamp(v1, -127, 127)) & 0xffu) << 8u;
  let b2 = (bitcast<u32>(clamp(v2, -127, 127)) & 0xffu) << 16u;
  let b3 = (bitcast<u32>(clamp(v3, -127, 127)) & 0xffu) << 24u;
  return b0 | b1 | b2 | b3;
}

@compute @workgroup_size(64, 1, 1)
fn main(@builtin(global_invocation_id) gid: vec3<u32>) {
  let l = gid.x;
  let t = gid.y;
  let bh = gid.z;

  let batch = meta_u(0u);
  let input_heads = meta_u(1u);
  let heads = meta_u(2u);
  let time = meta_u(3u);
  let embd = meta_u(4u);
  let latent_out = meta_u(5u);
  let artifact_latent = meta_u(6u);
  let activation_scale = scale_values[0u];
  let weight_scale = meta_values[7u];

  if (l >= latent_out || t >= time || bh >= batch * heads) {
    return;
  }

  let h = bh % heads;
  let b = bh / heads;
  var input_head = h;
  if (input_heads == 1u) {
    input_head = 0u;
  }

  var acc: i32 = 0;
  var e: u32 = 0u;
  let input_base = ((b * input_heads + input_head) * time + t) * embd;
  let weight_base = h * embd * artifact_latent + l;
  while (e + 4u <= embd) {
    let packed_input = pack_i8x4(
      input_codes[input_base + e],
      input_codes[input_base + e + 1u],
      input_codes[input_base + e + 2u],
      input_codes[input_base + e + 3u],
    );
    let packed_weight = pack_i8x4(
      weight_codes[weight_base + e * artifact_latent],
      weight_codes[weight_base + (e + 1u) * artifact_latent],
      weight_codes[weight_base + (e + 2u) * artifact_latent],
      weight_codes[weight_base + (e + 3u) * artifact_latent],
    );
    acc = dot4I8Packed(packed_input, packed_weight) + acc;
    e += 4u;
  }

  while (e < embd) {
    acc += input_codes[input_base + e] * weight_codes[weight_base + e * artifact_latent];
    e += 1u;
  }

  let output_index = ((b * heads + h) * time + t) * latent_out + l;
  output_values[output_index] = f32(acc) * activation_scale * weight_scale;
}