bugstalker 0.4.1

BugStalker is a modern and lightweight debugger for rust applications.
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77

{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    rust-overlay.url = "github:oxalica/rust-overlay";
    flake-parts.url = "github:hercules-ci/flake-parts";
  };

  outputs =
    inputs@{
      self,
      flake-parts,
      rust-overlay,
      ...
    }:
    flake-parts.lib.mkFlake { inherit self inputs; } {
      systems = [
        "x86_64-linux"
        "aarch64-linux"
      ];

      perSystem =
        {
          self',
          system,
          pkgs,
          ...
        }:
        {
          _module.args.pkgs = import inputs.nixpkgs {
            inherit system;

            overlays = [
              rust-overlay.overlays.default
            ];
          };

          apps.default = {
            type = "app";
            program = self'.packages.default;
          };

          packages = {
            default = self'.packages.bugstalker;
            bugstalker = pkgs.callPackage (import ./nix/package.nix) {
              rustPlatform =
                let
                  rust-bin = pkgs.rust-bin.fromRustupToolchainFile ./rust-toolchain.toml;
                in
                pkgs.makeRustPlatform {
                  cargo = rust-bin;
                  rustc = rust-bin;
                };
            };
          };

          checks = {
            inherit (self'.packages) bugstalker;
          };

          devShells.default =
            let
              bs = self'.packages.default;
              rust-toolchain = pkgs.rust-bin.fromRustupToolchainFile ./rust-toolchain.toml;
            in
            pkgs.mkShell {
              packages = [ rust-toolchain ] ++ bs.buildInputs ++ bs.nativeBuildInputs;
            };
        };

      flake = {
        homeManagerModules = rec {
          default = bugstalker;
          bugstalker = import ./nix/home-manager-module.nix self;
        };
      };
    };
}