brik 0.10.0

HTML tree manipulation library - a building block for HTML parsing and manipulation
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32

// Pest grammar for minimal HTML parsing to locate and modify the <html> tag
// Used for namespace injection before html5ever parsing

document = { SOI ~ preamble ~ html_tag ~ rest }

preamble = { (pi | doctype | comment | (!(pi | doctype | comment | html_tag) ~ ANY))* }

pi = { "<?" ~ (!"?>" ~ ANY)* ~ "?>" }

doctype = { "<!" ~ ^"DOCTYPE" ~ (!(">" | "[") ~ ANY)* ~ internal_subset? ~ ">" }

internal_subset = { "[" ~ (!"]>" ~ ANY)* ~ "]>" }

comment = { "<!--" ~ (!"-->" ~ ANY)* ~ "-->" }

html_tag = { "<" ~ ^"html" ~ attributes ~ whitespace? ~ tag_close }

attributes = { (whitespace ~ attribute)* ~ whitespace? }

attribute = { attr_name ~ (whitespace? ~ "=" ~ whitespace? ~ attr_value?)? }

attr_name = @{ (ASCII_ALPHA | "_" | ":") ~ (ASCII_ALPHANUMERIC | "_" | ":" | "-" | ".")* }

attr_value = @{
    ("\"" ~ (!"\"" ~ ANY)* ~ "\"") |
    ("'" ~ (!"'" ~ ANY)* ~ "'") |
    (!(whitespace | ">" | "/" | "=") ~ ANY)+
}

tag_close = { ">" | "/>" }
whitespace = _{ WHITE_SPACE+ }
rest = { ANY* }