brichka 0.2.2

Cli tools for databricks
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79

{
  description = "Kent";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-parts.url = "github:hercules-ci/flake-parts";
    make-shell.url = "github:nicknovitski/make-shell";
    rust-overlay.url = "github:oxalica/rust-overlay";

  };

  outputs =
    inputs@{
      flake-parts,
      make-shell,
      rust-overlay,
      ...
    }:
    flake-parts.lib.mkFlake { inherit inputs; } {
      imports = [
        make-shell.flakeModules.default
      ];
      systems = [
        "x86_64-linux"
        "aarch64-linux"
        "aarch64-darwin"
        "x86_64-darwin"
      ];
      perSystem =
        {
          pkgs,
          system,
          lib,
          ...
        }:
        let
          cargoToml = builtins.fromTOML (builtins.readFile ./Cargo.toml);

          rustPackage = pkgs.rust-bin.stable.latest.minimal;

          brichka =
            (pkgs.makeRustPlatform {
              cargo = rustPackage;
              rustc = rustPackage;
            }).buildRustPackage
              {
                inherit (cargoToml.package) name version;
                src = ./.;
                cargoLock.lockFile = ./Cargo.lock;
                nativeBuildInputs = [
                  rustPackage
                  pkgs.pkg-config
                ];
                buildInputs = [
                  pkgs.openssl
                ];
              };
        in
        {
          _module.args.pkgs = import inputs.nixpkgs {
            inherit system;
            overlays = [ (import rust-overlay) ];
          };

          make-shells = {
            default = {
              buildInputs = [ rustPackage ];
            };

            test.buildInputs = [ brichka ];
          };

          packages = {
            inherit brichka;
            default = brichka;
          };
        };
    };
}