brainterpreter 0.1.2

An interpreter for a Bauble toy programming language
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89

let memSize = 32;
let memory = [0; memSize];
let ip = 0;
let mem_p = 0;
let source = "++++++++++[>+++++++>++++++++++>+++>+<<<<-]>++.>+.+++++++..+++.>++.<<+++++++++++++++.>.+++.------.--------.>+.>.";
// let source = "++++++++++[-].";

fun inc() {
	let mem_v = memory[mem_p];
	mem_v = mem_v + 1;
	if (mem_v > 255) {
		mem_v = 0;
	}
	memory[mem_p] = mem_v;
}

fun dec() {
	let mem_v = memory[mem_p];
	mem_v = mem_v - 1;
	if (mem_v < 0) {
		mem_v = 255;
	}
	memory[mem_p] = mem_v;
}

fun mem_next() {
	mem_p = mem_p + 1;
}

fun mem_prev() {
	mem_p = mem_p - 1;
}

fun out() {
	let c = memory[mem_p];
	print as_string(as_char(c));
}

fun loop_forward() {
	if (memory[mem_p] == 0) {
		let nested_level = 1;
		while (nested_level > 0) {
		 	ip = ip + 1;
			let c = source[ip];
			if (c == "[") {
				nested_level = nested_level + 1;
			}
			if (c == "]") {
				nested_level = nested_level - 1;
			}
		}
	}
}

fun loop_backward() {
	if (memory[mem_p] != 0) {
		let nested_level = 1;
		while (nested_level > 0) {
		 	ip = ip - 1;
			let c = source[ip];
			if (c == "]") {
				nested_level = nested_level + 1;
			}
			if (c == "[") {
				nested_level = nested_level - 1;
			}
		}
	}
}

while (ip < len(source)) {
	let c = source[ip];
	if (c == "+") {
		inc();
	} else if (c == "-") {
		dec();
	} else if (c == "<") {
		mem_prev();
	} else if (c == ">") {
		mem_next();
	} else if (c == "[") {
		loop_forward();
	} else if (c == "]") {
		loop_backward();
	} else if (c == ".") {
		out();
	}
	ip = ip + 1;
}