bomper 0.5.1

bumps versions in files
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95

{
  description = "bumps versions in files";

  inputs = {
    nixpkgs.url = "nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
    flake-parts = {
      url = "github:hercules-ci/flake-parts";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    pre-commit-hooks.url = "github:cachix/pre-commit-hooks.nix";
    gitignore = {
      url = "github:hercules-ci/gitignore.nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    bomper = {
      url = "github:justinrubek/bomper";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = {
    self,
    nixpkgs,
    flake-utils,
    flake-parts,
    gitignore,
    rust-overlay,
    pre-commit-hooks,
    bomper,
    ...
  }:
    flake-parts.lib.mkFlake {inherit self;} {
      perSystem = {
        config,
        self',
        inputs',
        pkgs,
        system,
        ...
      }: let
        inherit (gitignore.lib) gitignoreSource;
        pre-commit-check = pre-commit-hooks.lib.${system}.run {
          src = gitignoreSource ./.;
          hooks = {
            alejandra.enable = true;
            rustfmt.enable = true;
          };
        };

        opkgs = import nixpkgs {
          inherit system;
          overlays = [
            rust-overlay.overlays.default
          ];
        };
        rust = opkgs.rust-bin.stable.latest.default;
        rustPackage = pkgs.rustPlatform.buildRustPackage {
          pname = "bomper";
          version = "0.5.1";

          src = gitignoreSource ./.;
          cargoLock = {
            lockFile = ./Cargo.lock;
          };
          nativeBuildInputs = [rust];
        };

        bomper-cli = bomper.packages.${system}.cli;
      in rec {
        packages = {
          cli = rustPackage;
          default = packages.cli;
        };
        devShells = {
          default = pkgs.mkShell rec {
            buildInputs = with pkgs; [rust rustfmt cocogitto bomper-cli];
            inherit (pre-commit-check) shellHook;
          };
        };
        apps = {
          cli = {
            type = "app";
            program = "${packages.cli}/bin/bomper";
          };
          default = apps.cli;
        };
      };
      systems = flake-utils.lib.defaultSystems;
    };
}