bip0039 0.13.0

Another Rust implementation of BIP-0039 standard
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

# bip0039 specific justfile

# Import shared recipes from root
import "../justfile"

# Run a benchmark: `just bench <name> [args]`
[positional-arguments]
[working-directory('benchmarks')]
bench name *args:
    #!/usr/bin/env bash
    set -eo pipefail
    if [ -n "{{ args }}" ]; then
        echo "Running benchmark \"{{ name }}\" with: {{ args }}"
        cargo bench --bench {{ name }} -- {{ args }}
    else
        echo "Running benchmark \"{{ name }}\""
        cargo bench --bench {{ name }} -- --quiet
    fi

# Run all benchmarks: `just benches [args]`
[positional-arguments]
[working-directory('benchmarks')]
benches *args:
    #!/usr/bin/env bash
    set -eo pipefail
    if [ -n "{{ args }}" ]; then
        echo "Running all benchmarks with: {{ args }}"
        cargo bench -- {{ args }}
    else
        echo "Running all benchmarks"
        cargo bench -- --quiet
    fi

# Run fuzz: `just fuzz <target> [runs]`
[positional-arguments]
[working-directory('fuzz')]
fuzz target runs='1000':
    #!/usr/bin/env bash
    set -eo pipefail
    echo "Running fuzzer on target \"{{ target }}\" with {{ runs }} runs"
    cargo +nightly fuzz run {{ target }} -- -runs={{ runs }}

# Cleanup fuzz artifacts
[working-directory('fuzz')]
fuzz-clean:
    #!/usr/bin/env bash
    set -eo pipefail
    rm -rf artifacts corpus