bevy_webgl2 0.5.2

A webgl2 wasm32 render backend for Bevy Engine
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83

#version 300 es

layout(location = 0) in vec3 Vertex_Position;
layout(location = 1) in vec3 Vertex_Normal;
layout(location = 2) in vec2 Vertex_Uv;

out vec2 v_Uv;
out vec4 v_Color;

layout(std140) uniform CameraViewProj {
    mat4 ViewProj;
};

// TODO: merge dimensions into "sprites" buffer when that is supported in the Uniforms derive abstraction
layout(std140) uniform TextureAtlas_size {  // set = 1, binding = 0
    vec2 AtlasSize;
};

struct Rect {
    vec2 begin;
    vec2 end;
};

layout(std140) uniform TextureAtlas_textures {  // set = 1, binding = 1
    Rect[256] Textures;
};


layout(std140) uniform Transform {  // set = 2, binding = 0
    mat4 SpriteTransform;
};

layout(std140) uniform TextureAtlasSprite { // set = 2, binding = 1
    vec4 color;
    uint index;
    uint flip;
};

void main() {
    Rect sprite_rect = Textures[index];
    vec2 sprite_dimensions = sprite_rect.end - sprite_rect.begin;
    vec3 vertex_position = vec3(Vertex_Position.xy * sprite_dimensions, 0.0);

    // Specify the corners of the sprite
    vec2 bottom_left = vec2(sprite_rect.begin.x, sprite_rect.end.y);
    vec2 top_left = sprite_rect.begin;
    vec2 top_right = vec2(sprite_rect.end.x, sprite_rect.begin.y);
    vec2 bottom_right = sprite_rect.end;

    // Flip the sprite if necessary
    uint x_flip_bit = 1u;
    uint y_flip_bit = 2u;

    vec2 tmp;
    if ((flip & x_flip_bit) == x_flip_bit) {
        // Shuffle the corners to flip around x
        tmp = bottom_left;
        bottom_left = bottom_right;
        bottom_right = tmp;
        tmp = top_left;
        top_left = top_right;
        top_right = tmp;
    }
    if ((flip & y_flip_bit) == y_flip_bit) {
        // Shuffle the corners to flip around y
        tmp = bottom_left;
        bottom_left = top_left;
        top_left = tmp;
        tmp = bottom_right;
        bottom_right = top_right;
        top_right = tmp;
    }

    vec2 atlas_positions[4] = vec2[](
        bottom_left,
        top_left,
        top_right,
        bottom_right
    );
    v_Uv = atlas_positions[gl_VertexID] / AtlasSize;
    v_Color = color;
    gl_Position = ViewProj * SpriteTransform * vec4(ceil(vertex_position), 1.0);
}