bevy_ecs_tiled 0.13.3

A Bevy plugin for loading Tiled maps
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66

set default-list := true
doc_features := "debug,user_properties,physics,avian,rapier"

# Control simultaneous linking operations when building
jobs_arg := if env("BUILD_NJOBS", "0") != "0" {
    "--jobs $BUILD_NJOBS"
} else {
    ""
}

# Comment out this if not using rust nightly
export RUSTFLAGS := "-Dwarnings -Zshare-generics=y -Zthreads=0 -C debuginfo=line-tables-only"
export RUSTDOCFLAGS := "-Dwarnings -Zshare-generics=y -Zthreads=0 -C debuginfo=line-tables-only"

#### High-level checks jobs

check: clippy fmt build

check-ci: check doc-test build-all test doc-build book-build

check-all: check-ci check-all-features

check-release: check-all
    cargo publish --dry-run

#### Low-level checks jobs

clippy:
    cargo clippy --workspace --all-targets --all-features -- --deny warnings

fmt:
    cargo fmt --all -- --check

test: build-tests
    cargo test {{ jobs_arg }} --workspace --all-features

#### Build jobs

build: build-lib

build-all: build-lib build-tests build-examples

build-lib:
    cargo build --workspace --all-features --lib

build-examples: build-lib
    cargo build {{ jobs_arg }} --workspace --all-features --examples

build-tests: build-lib
    cargo build {{ jobs_arg }} --workspace --all-features --tests
check-all-features:
    cargo check-all-features

#### Documentation jobs

doc-test:
    cargo test --workspace --doc --all-features

doc-build:
    cargo doc --features={{ doc_features }}

book-build:
    mdbook --version &>/dev/null && (cd ./book && mdbook build)

book-serve:
    mdbook --version &>/dev/null && (cd ./book && mdbook serve)