bend-lang 0.2.33

A high-level, massively parallel programming language
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37

def insertion_sort(xs):
  match xs:
    case List/Nil:
      return List/Nil
    case List/Cons:
      return insertion_sort.insert(xs.head, insertion_sort(xs.tail))

# Inserts a value into a partially sorted list
def insertion_sort.insert(v, xs):
  match xs:
    case List/Nil:
      return List/Cons(v, List/Nil)
    case List/Cons:
      return insert_aux(v > xs.head, v, xs.head, xs.tail)

def insert_aux(n, v, x, xs):
  if n == 0:
    return List/Cons(v, List/Cons(x, xs))
  else:
    return List/Cons(x, insertion_sort.insert(v, xs))

# Generates a list of random numbers
def rnd(n):
  if n == 0:
    return List/Nil
  else:
    return List/Cons(random(10000 - n), rnd(n - 1))

# Generates a pseudo-random number (not very good)
def random(n):
  if n == 0:
    return 0
  else:
    return (random(n - 1) * 16 + 101387) % 429453

def main():
  return insertion_sort(rnd(10))