beans 6.6.0

A parser generator library based on the Earley parser
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145

Option[content] ::=
  content@value <Some>
  <None>;

NonEmptyList[content, separation] ::=
  content@head <Nil>
  content@head separation NonEmptyList[content, separation]@tail <Cons>;

List[content, separation] ::=
  Option[NonEmptyList[content, separation]]@value <>;

Empty ::=
  <>;

"a file"
@File ::=
  List[INCLUDE, Empty] List[FunctionDeclaration, Empty]@decls <>;

"a function declaration"
FunctionDeclaration ::=
  Type@rettype IDENT.0@name LPAR List[TypedParam, COMMA]@args RPAR Block@block <>;

"a type"
Type ::=
  VOID <Void>
  INTTY <Int>
  BOOL <Bool>
  Type@pointed ASTERISK <Pointer>;

"a parameter"
TypedParam ::=
  Type@type IDENT.0@name <>;

"an integer"
Int ::=
  INT.0@value <Int>
  CHAR.0@value <Char>;

"a boolean"
Bool ::=
  TRUE <True>
  FALSE <False>;

"an expression"
Expr ::=
  Int@value <Int>
  Bool@value <Bool>
  NULL <Null>
  LPAR Expr@this RPAR <Through>
  EXCLAM Expr@value <Not>
  PLUSPLUS Expr@value <Incrl>
  Expr@value PLUSPLUS <Incrr>
  MINUSMINUS Expr@value <Decrl>
  Expr@value MINUSMINUS <Decrr>
  AMPERSAND Expr@value <Borrow>
  ASTERISK Expr@value <Deref>
  PLUS Expr@value <Plus>
  MINUS Expr@value <Minus>
  IDENT.0@value <Ident>
  SIZEOF LPAR Type@type RPAR <Sizeof>
  IDENT.0@name LPAR List[Expr, COMMA]@args RPAR <Call>
  Expr@array LBRACKET Expr@index RBRACKET <
    Deref
    value: Expr {
      BinOp
      op: AddSubOp { Add }
      left: array
      right: index
    }
  >
  (left-assoc) Expr@left MulDivModOp@op Expr@right <BinOp>
  (left-assoc) Expr@left AddSubOp@op Expr@right <BinOp>
  (left-assoc) Expr@left CmpOp@op Expr@right <BinOp>
  (left-assoc) Expr@left EqOp@op Expr@right <BinOp>
  (left-assoc) Expr@left AndOp@op Expr@right <BinOp>
  (left-assoc) Expr@left OrOp@op Expr@right <BinOp>
  (right-assoc) Expr@key EQUAL Expr@value <Assign>;

"an operator"
MulDivModOp ::=
  ASTERISK <Mul>
  SLASH <Div>
  PERCENT <Mod>;

"an operator"
AddSubOp ::=
  PLUS <Add>
  MINUS <Sub>;

"an operator"
CmpOp ::=
  LT <Lt>
  GT <Gt>
  GEQ <Geq>
  LEQ <Leq>;

"an operator"
EqOp ::=
  EQ <Equal>
  NEQ <NotEqual>;

"an operator"
AndOp ::=
  AND <And>;

"an operator"
OrOp ::=
  OR <Or>;

"a statement"
Statement ::=
  SEMICOLON <None>
  Expr@stmt SEMICOLON <Regular>
  IF LPAR Expr@condition RPAR Statement@then Option[Else]@else <If>
  WHILE LPAR Expr@condition RPAR Statement@body <While>
  FOR
    LPAR
      Option[VariableDeclaration]@init SEMICOLON
      Option[Expr]@test SEMICOLON
      List[Expr, COMMA]@step
    RPAR
    Statement@body <For>
  Block@stmts <Block>
  RETURN Option[Expr]@value SEMICOLON <Return>
  BREAK SEMICOLON <Break>
  CONTINUE SEMICOLON <Continue>;

Else ::=
  ELSE Statement@else <>;

"a block"
Block ::=
  LBRACE List[DeclStatement, Empty]@stmts RBRACE <>;

DeclStatement ::=
  FunctionDeclaration@declaration <Function>
  VariableDeclaration@declaration SEMICOLON <Declaration>
  Statement@stmt <Statement>;

"a variable declaration"
VariableDeclaration ::=
  Type@type IDENT.0@name Option[Definition]@value <>;

Definition ::=
  EQUAL Expr@value <>;