basic-cookies 0.1.5

Low-level RFC 6265 combatible cookie handling library for Rust.
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97

use crate::{CookieLexerError, CookieToken};
use crate::cookie::terminals::Cookie;
use crate::cookie::nonterminals::NonTerminalSpan;
use crate::linked_list::LinkedList;

grammar;

pub(crate) Cookies: LinkedList<Cookie> = {
    <CookieString> => <>,
    OWS <CookieString> => <>,
    <CookieString> OWS => <>,
    OWS <CookieString> OWS => <>
}

CookieString: LinkedList<Cookie> = {
    <c: Cookie> => LinkedList::new(c),
    <cv: CookieString> ";" " " <c: Cookie> => cv.insert(c),
    <cv: CookieString> ";" <c: Cookie> => cv.insert(c)
}

Cookie: Cookie = {
    <t: Token> "=" <c: PossiblyQuotedCookieOctets> => Cookie {
        key: t,
        value: c
    },
    <l: @L> "=" <c: PossiblyQuotedCookieOctets> => Cookie {
        key: NonTerminalSpan::new(l, l),
        value: c
    },
    <t: Token> "=" <r: @R> => Cookie {
        key: t,
        value: NonTerminalSpan::new(r, r)
    },
    <l: @L> "=" <r: @R> => Cookie {
        key: NonTerminalSpan::new(l, l),
        value: NonTerminalSpan::new(r, r)
    },
    <l: @L> <c: PossiblyQuotedNoEqualsCookieOctets> => Cookie {
        key: NonTerminalSpan::new(l, l),
        value: c
    },
};

PossiblyQuotedCookieOctets: NonTerminalSpan = {
    <CookieOctets> => <>,
    "\"" <c: CookieOctets> "\"" => <>
}

PossiblyQuotedNoEqualsCookieOctets: NonTerminalSpan = {
    <NoEqualsCookieOctets> => <>,
    "\"" <c: NoEqualsCookieOctets> "\"" => <>
}

Token: NonTerminalSpan = {
    <l: @L> "token_or_cookie_octets" <r: @R> => NonTerminalSpan::new(l, r)
}

NoEqualsCookieOctets: NonTerminalSpan = {
    <l: @L> "cookie_octets" <r: @R> => NonTerminalSpan::new(l, r),
    <l: @L> "token_or_cookie_octets" <r: @R> => NonTerminalSpan::new(l, r),
    <l: @L> NoEqualsCookieOctets "cookie_octets" <r: @R> => NonTerminalSpan::new(l, r),
    <l: @L> NoEqualsCookieOctets "token_or_cookie_octets" <r: @R> => NonTerminalSpan::new(l, r)
}

CookieOctets: NonTerminalSpan = {
    <l: @L> "cookie_octets" <r: @R> => NonTerminalSpan::new(l, r),
    <l: @L> "token_or_cookie_octets" <r: @R> => NonTerminalSpan::new(l, r),
    <l: @L> "=" <r: @R> => NonTerminalSpan::new(l, r),
    <l: @L> CookieOctets "cookie_octets" <r: @R> => NonTerminalSpan::new(l, r),
    <l: @L> CookieOctets "token_or_cookie_octets" <r: @R> => NonTerminalSpan::new(l, r),
    <l: @L> CookieOctets "=" <r: @R> => NonTerminalSpan::new(l, r)
}

OWS: () = {
    OWSPart => (),
    OWSPart OWS => ()
}

OWSPart: () = {
    " " => (),
    "ws" => (),
}

extern {
    type Location = usize;
    type Error = CookieLexerError;

    enum CookieToken {
        "cookie_octets" => CookieToken::CookieOctets,
        "token_or_cookie_octets" => CookieToken::TokenOrCookieOctets,
        "=" => CookieToken::Equals,
        ";" => CookieToken::Semicolon,
        " " => CookieToken::Space,
        "ws" => CookieToken::Whitespace,
        "\"" => CookieToken::DoubleQuote
    }
}