badness 0.5.0

A language server, formatter, and linter for LaTeX
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81

{
  description = "A language server, formatter, and linter for LaTeX";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs =
    {
      self,
      nixpkgs,
      flake-utils,
    }:
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = import nixpkgs {
          inherit system;
        };

        badness = pkgs.rustPlatform.buildRustPackage {
          pname = "badness";
          version = "0.4.0";

          src = ./.;

          cargoLock = {
            lockFile = ./Cargo.lock;
            outputHashes = {
              "distro-0.0.0" = "sha256-qPPmCn9qAzZuMDJS8AM1EVT0LomrhNgPfhcL/PAIZ0k=";
            };
          };

          nativeBuildInputs = [ pkgs.installShellFiles ];

          postInstall = ''
            installShellCompletion --cmd badness \
              --bash target/completions/badness.bash \
              --fish target/completions/badness.fish \
              --zsh target/completions/_badness

            installManPage target/man/*
          '';

          meta = with pkgs.lib; {
            description = "A language server, formatter, and linter for LaTeX";
            homepage = "https://github.com/jolars/badness";
            license = licenses.mit;
            maintainers = [ ];
          };
        };
      in
      {
        packages = {
          default = badness;
          badness = badness;
        };

        apps = {
          default = {
            type = "app";
            program = "${badness}/bin/badness";
          };
        };

        devShells.default = pkgs.mkShell {
          buildInputs = with pkgs; [
            cargo
            rustc
            rustfmt
            clippy
            rust-analyzer
            go-task
            wasm-pack
            llvmPackages.bintools
          ];
        };
      }
    );
}