axum-postgres-tx 0.2.0

Request-scoped PostgreSQL transactions for axum
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114

{
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
    flake-parts.url = "github:hercules-ci/flake-parts";
    treefmt.url = "github:numtide/treefmt-nix";
    git-hooks.url = "github:cachix/git-hooks.nix";
    git-hooks.inputs.nixpkgs.follows = "nixpkgs";
    crane.url = "github:ipetkov/crane";
    advisory-db.url = "github:rustsec/advisory-db";
    advisory-db.flake = false;
  };

  outputs = inputs @ {
    flake-parts,
    treefmt,
    git-hooks,
    crane,
    advisory-db,
    ...
  }:
    flake-parts.lib.mkFlake {inherit inputs;} {
      systems = ["aarch64-darwin" "aarch64-linux" "x86_64-darwin" "x86_64-linux"];

      imports = [
        treefmt.flakeModule
        git-hooks.flakeModule
      ];

      perSystem = {
        config,
        pkgs,
        lib,
        ...
      }: let
        craneLib = crane.mkLib pkgs;
        src = craneLib.cleanCargoSource ./.;

        commonArgs = {
          inherit src;
          strictDeps = true;
          buildInputs = [] ++ lib.optionals pkgs.stdenv.isDarwin [pkgs.libiconv];
        };

        cargoArtifacts = craneLib.buildDepsOnly commonArgs;

        axum-postgres-tx = craneLib.buildPackage (commonArgs
          // {
            inherit cargoArtifacts;
            meta.mainProgram = "axum-postgres-tx";
          });
      in {
        checks = {
          inherit axum-postgres-tx;

          axum-postgres-tx-clippy = craneLib.cargoClippy (
            commonArgs
            // {
              inherit cargoArtifacts;
              cargoClippyExtraArgs = "--all-targets -- --deny warnings";
            }
          );

          axum-postgres-tx-doc = craneLib.cargoDoc (commonArgs // {inherit cargoArtifacts;});
          axum-postgres-tx-audit = craneLib.cargoAudit {inherit src advisory-db;};
          axum-postgres-tx-deny = craneLib.cargoDeny {inherit src;};

          axum-postgres-tx-nextest = craneLib.cargoNextest (
            commonArgs
            // {
              inherit cargoArtifacts;
              partitions = 1;
              partitionType = "count";
              cargoNextestPartitionsExtraArgs = "--no-tests=pass";
            }
          );
        };

        packages.default = axum-postgres-tx;

        apps.default = {
          type = "app";
          program = lib.getExe axum-postgres-tx;
          meta.description = "";
        };

        treefmt.programs = {
          alejandra.enable = true; # nix
          rustfmt.enable = true; # rust
          taplo.enable = true; # toml
        };

        pre-commit.settings.hooks = {
          treefmt.enable = true;
          treefmt.package = config.treefmt.build.wrapper;
        };

        devShells.default = craneLib.devShell {
          checks = config.checks;

          shellHook = ''
            ${config.pre-commit.installationScript}
          '';

          packages = with pkgs;
            [
              rust-analyzer # rust lsp
              nil # nix lsp
            ]
            ++ config.pre-commit.settings.enabledPackages
            ++ lib.attrValues config.treefmt.build.programs;
        };
      };
    };
}