autosway 0.4.1

Automation program
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64

{
  description = "autosway Nix flake";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs?ref=nixos-unstable";

    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    flake-utils = {url = "github:numtide/flake-utils";};
  };

  outputs = {
    self,
    nixpkgs,
    ...
  } @ inputs:
    inputs.flake-utils.lib.eachSystem [
      "x86_64-linux"
      "aarch64-linux"
      "x86_64-darwin"
      "aarch64-darwin"
    ] (system: let
      pkgs = nixpkgs.legacyPackages.${system};
    in {
      packages.autosway = let
        manifest = (pkgs.lib.importTOML ./Cargo.toml).package;
      in
        pkgs.rustPlatform.buildRustPackage {
          pname = manifest.name;
          version = manifest.version;
          cargoLock.lockFile = ./Cargo.lock;
          src = pkgs.lib.cleanSource ./.;

          nativeBuildInputs = with pkgs; [
            pkg-config
            rustfmt
            clippy
            rust-analyzer
          ];

          buildInputs = with pkgs;
            []
            ++ lib.optionals (lib.strings.hasSuffix "linux" system) [
              alsa-oss
              alsa-lib
              openssl
            ];
        };

      packages.default = self.packages.${system}.autosway;
    })
    // {
      homeManagerModules.autosway = {pkgs, ...} @ args: {
        imports = [
          (import ./nix/homeManagerModules/autosway.nix inputs {
            inherit (self.packages.${pkgs.system}) autosway;
          })
        ];
      };
    };
}