autocorrect 2.14.2

A linter and formatter for help you improve copywriting, to correct spaces, words, punctuations between CJK (Chinese, Japanese, Korean).
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27

//! Elixir Parser
item       = _{ SOI ~ line* ~ EOI }
line       = _{ regexp | string | other }
other      = ${ !(string) ~ ANY }
WHITESPACE =  { " " | "\t" | NEWLINE }

/// Comment
line_comment  = _{ "#" ~ (!(NEWLINE) ~ ANY)* }
block_comment = _{ "\"\"\"" ~ (!("\"\"\"") ~ ANY)* ~ "\"\"\"" }
COMMENT       = ${ line_comment | block_comment }

/// String
string       = ${
    inner_string
  | ("\"\"\"" ~ (!("\"\"\"") ~ ANY)* ~ "\"\"\"")
  | ("~" ~ ("s" | "c") ~ "(" ~ (!(NEWLINE | ")") ~ ANY)* ~ ")")
}
inner_string = _{
    ("'" ~ (!(inner_string | "'") ~ ANY)* ~ "'")
  | ("\"" ~ (!(inner_string | "\"") ~ ANY)* ~ "\"")
}

/// Regex
regexp = ${
    ("~r/" ~ (!(inner_string | "/") ~ ANY)* ~ "/")
  | ("Regex.compile(" ~ " "* ~ inner_string ~ (!")" ~ ANY)* ~ ")")
}