asdi 0.2.5

Another Simplistic Datalog Implementation (in Rust)
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140

program ::= pragma* ( fact | rule | query )*

/* ************************************************************************* */

fact    ::= predicate ( "(" constant ( "," constant )* ")" )? "."

predicate
        ::= LC_ALPHA ( ALPHA | DIGIT | "_" )*

/* ************************************************************************* */

constant
        ::= string | number | boolean

string  ::= predicate ( ":" ALPHA ( ALPHA | DIGIT | "_" * )? )
            | DQUOTE [^\"]* DQUOTE

number  ::= float | decimal | integer

integer ::= ( "+" | "-" )? DIGIT+

decimal ::= integer "." DIGIT+

float   ::= decimal ( "e" | "E" ) integer

boolean ::= ( "true" | "⊤" ) | ( "false" | "⊥" )

/* ************************************************************************* */

rule    ::= ( head | "⊥" )? ( ":-" | "<-" | "⟵" ) body "."

head    ::= ( atom ( ( ";" | "|" | "OR" | "∨" ) atom )* )

body    ::= literal ( ( "," | "&" | "AND" | "∧" ) literal )*


/* ************************************************************************* */

atom    ::= predicate "(" term ( "," term )* ")"

term    ::= variable | constant

variable
        ::= named-variable | anon-variable

named-variable
        ::= UC_ALPHA ( ALPHA | DIGIT | "_" )*

anon-variable
        ::= "_"

/* ************************************************************************* */

literal
        ::= ( "!" | "NOT" | "￢" )? ( atom | comparison )

/* ************************************************************************* */

comparison
        ::= ( named-variable | constant ) operator ( named-variable | constant )

operator
        ::= "="
            | ("!=" | "/=" | "≠")
            | "<"
            | ("<=" | "≤")
            | ">"
            | (">=" | "≥")
            | ("*=" | "≛" | "MATCHES")

/* ************************************************************************* */

query   ::= ( "?-" atom "." ) | ( atom "?" )

/* ************************************************************************* */

pragma  ::= "." ( feature | assert | infer | fd | input | output ) "."

feature
        ::= "feature" "(" feature-id ( "," feature-id )* ")"

feature-id
        ::= "comparisons"
        | "constraints"
        | "disjunction"
        | "negation"
        | "functional_dependencies"

assert  ::= "assert" predicate "(" attribute-decl ( "," attribute-decl )* ")"

attribute-decl
        ::= ( predicate ":" )? ( "boolean" | "integer" | "string" )

infer   ::= "infer"
            ( predicate "(" attribute-decl ( "," attribute-decl )* ")"
            | "from" predicate ) "."

fd      ::= ( "fd" | "functional_dependency" )
            predicate ":"
            attribute-index-list ( "-->" | "⟶" ) attribute-index-list

attribute-index-list
        ::= attribute-index ( "," attribute-index )*

attribute-index
        ::= integer | predicate

input   ::= "input" io-details

io-details
        ::= "(" predicate "," quoted-string ( "," quoted-string )? ")"

output  ::= "output" io-details

/* ************************************************************************* */

comment ::= "%" [^\r\n]* EOL
            | '/*' ( [^*] | '*'+ [^*/] )* '*'* '*/'

/* ************************************************************************* */

/*
EOL     ::= "\n" | "\\r\\n" | "\r"

WHITESPACE
        ::= " " | "\t" | EOL

DQUOTE
        ::= '"'

LC_ALPHA
        ::= ? corresponds to the Unicode category 'Ll' ?

UC_ALPHA
        ::= ? corresponds to the Unicode category 'Lu' ?

ALPHA   ::= LC_ALPHA | UC_ALPHA

DIGIT   ::= ? corresponds to the Unicode category 'Nd' (decimal number) ?
*/