am 0.5.2

A beautiful and feature-packed Apple Music CLI
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69

{
  lib,
  stdenv,
  pkg-config,
  rustPlatform,
  installShellFiles,
  CoreFoundation,
  Security,
  SystemConfiguration,
  IOKit,
  libiconv,
  version,
  self,
  lto ? true,
  optimizeSize ? true,
}: let
  filter = path: type: let
    path' = toString path;
    base = baseNameOf path';

    matches = lib.any (suffix: lib.hasSuffix suffix base) [".rs" ".toml"];
    isLock = base == "Cargo.lock";
  in
    type == "directory" || matches || isLock;

  filterSource = src:
    lib.cleanSourceWith {
      src = lib.cleanSource src;
      inherit filter;
    };
in
  rustPlatform.buildRustPackage rec {
    pname = "am";
    inherit version;

    src = filterSource self;
    cargoLock.lockFile = ./Cargo.lock;

    RUSTFLAGS =
      lib.optionalString lto " -C lto=fat -C embed-bitcode=yes"
      + lib.optionalString optimizeSize " -C codegen-units=1 -C strip=symbols -C opt-level=z";

    buildInputs = lib.optionals stdenv.isDarwin [
      CoreFoundation
      Security
      SystemConfiguration
      IOKit
      libiconv
    ];

    nativeBuildInputs = [
      pkg-config
      installShellFiles
    ];

    postInstall = ''
      installShellCompletion --cmd ${pname} \
        --bash <("$out/bin/${pname}" completions bash) \
        --zsh <("$out/bin/${pname}" completions zsh) \
        --fish <("$out/bin/${pname}" completions fish)
    '';

    meta = with lib; {
      description = "Minimal Apple Music CLI";
      maintainers = with maintainers; [ryanccn];
      license = licenses.gpl3Only;
      mainProgram = "am";
    };
  }