algebraeon-geometry 0.0.17

Algorithms for working with geometric shapes
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62

grammar;
use crate::parse::ast::*;
use std::string::String;

pub Value: String = {
    r"[a-zA-Z0-9/]*" => String::from(<>)
}

pub SignedValue: SignedValue = {
    Value => SignedValue {sign : Sign::Positive, value : <>},
    "+" <v:Value> => SignedValue {sign : Sign::Positive, value : v},
    "-" <v:Value> => SignedValue {sign : Sign::Negative, value : v},
}

pub Point: Point = {
    "(" <coordinates: Comma<SignedValue>> ")" => Point { coordinates }
};

pub AtomicShape: ShapeExpression = {
    "(" <s: Shape> ")" => s,
    Point => ShapeExpression::Point(<>),
    "ConvexHull" "(" <pts:Comma<Point>> ")" => ShapeExpression::ConvexHull(pts),
    "ConvexHullInterior" "(" <pts:Comma<Point>> ")" => ShapeExpression::ConvexHullInterior(pts),
    "ConvexHullBoundary" "(" <pts:Comma<Point>> ")" => ShapeExpression::ConvexHullBoundary(pts),
    "Lines" "(" <pts:Comma<Point>> ")" => ShapeExpression::Lines(pts),
    "Loop" "(" <pts:Comma<Point>> ")" => ShapeExpression::Loop(pts),
    "Polygon" "(" <pts:Comma<Point>> ")" => ShapeExpression::Polygon(pts),
    "PolygonInterior" "(" <pts:Comma<Point>> ")" => ShapeExpression::PolygonInterior(pts),
}

pub ShapeUnion: ShapeExpression = {
    <s1: AtomicShape> "|" <s2: AtomicShape> => ShapeExpression::Union(Box::new(s1), Box::new(s2)),
    <s1: ShapeUnion> "|" <s2: AtomicShape> => ShapeExpression::Union(Box::new(s1), Box::new(s2)),
}

pub ShapeIntersect: ShapeExpression = {
    <s1: AtomicShape> "&" <s2: AtomicShape> => ShapeExpression::Intersect(Box::new(s1), Box::new(s2)),
    <s1: ShapeIntersect> "&" <s2: AtomicShape> => ShapeExpression::Intersect(Box::new(s1), Box::new(s2)),
}

pub ShapeMinkowskiSum: ShapeExpression = {
    <s1: AtomicShape> "+" <s2: AtomicShape> => ShapeExpression::MinkowskiSum(Box::new(s1), Box::new(s2)),
    <s1: ShapeMinkowskiSum> "+" <s2: AtomicShape> => ShapeExpression::MinkowskiSum(Box::new(s1), Box::new(s2)),
}

pub Shape: ShapeExpression = {
    <s:AtomicShape> => <>,
    <s: ShapeUnion> => s,
    <s: ShapeIntersect> => s,
    <s: ShapeMinkowskiSum> => s,
    <s1: AtomicShape> "\\" <s2: AtomicShape> => ShapeExpression::Difference(Box::new(s1), Box::new(s2)),
}

Comma<T>: Vec<T> = {
    <mut v:(<T> ",")*> <e:T?> => match e {
        None => v,
        Some(e) => {
            v.push(e);
            v
        }
    }
};