air-lambda-parser 0.1.0

Parser of an AIR lambda
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54

use crate::ValueAccessor;
use crate::parser::lambda_parser::RawLambdaAST;
use crate::Functor;
use crate::parser::lexer::LexerError;
use crate::parser::lexer::Token;

use lalrpop_util::ErrorRecovery;

// the only thing why input matters here is just introducing lifetime for Token
grammar<'err, 'input>(input: &'input str, errors: &'err mut Vec<ErrorRecovery<usize, Token<'input>, LexerError>>);

pub(crate) RawLambdaAST: RawLambdaAST<'input> = {
    <value_path_starter: ".$"> <accessors: ValueAccessor*> => RawLambdaAST::ValuePath(accessors),

    length_functor => RawLambdaAST::Functor(Functor::Length),

    ! => { errors.push(<>); RawLambdaAST::Error },
}

ValueAccessor: ValueAccessor<'input> = {
    <maybe_dot_selector:"."?> "[" <idx: number_accessor> "]" <maybe_flatten_sign:"!"?> => {
        ValueAccessor::ArrayAccess { idx }
    },

    <maybe_dot_selector:"."?> "[" <scalar_name: string_accessor> "]" <maybe_flatten_sign:"!"?> => {
        ValueAccessor::FieldAccessByScalar { scalar_name }
    },

    "." <field_name: string_accessor> <maybe_flatten_sign:"!"?> => {
        ValueAccessor::FieldAccessByName { field_name }
    },

    ! => { errors.push(<>); ValueAccessor::Error },
}

extern {
    type Location = usize;
    type Error = LexerError;

    enum Token<'input> {
        ".$" => Token::ValuePathStarter,
        "." => Token::ValuePathSelector,

        "[" => Token::OpenSquareBracket,
        "]" => Token::CloseSquareBracket,

        number_accessor => Token::NumberAccessor(<u32>),
        string_accessor => Token::StringAccessor(<&'input str>),

        "!" => Token::FlatteningSign,

        length_functor => Token::LengthFunctor,
    }
}