ahiru-tpm 0.4.0

Drop-in replacement for the famous Tmux Plugin Manager (TPM), written in Rust. 🦆
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30

WHITESPACE = _{ " " | "\t" }
COMMENT    = _{ "#" ~ (!newline ~ ANY)* }

config    = _{ SOI ~ (directive+ | newline)* ~ EOI }
directive = _{ ((plugin_spec | source | other) ~ (newline | EOI)) }

newline = _{ "\r" | "\n" }

plugin_spec =  { set_option ~ "-g" ~ "@plugin" ~ quoted_string }
source      =  { source_file ~ source_file_flags ~ quoted_string }
other       = @{ ("\\" ~ newline | !newline ~ ANY)+ }

set_option  = @{ "set" ~ ("-option")? }
source_file = @{ "source" ~ ("-file")? }

source_file_flags = @{ ("-" ~ (ASCII_ALPHANUMERIC+) ~ WHITESPACE)* }

// 
// --- Quoted String ----------------------------------------------------------
// 
quoted_string = ${ (single_quoted | double_quoted) }

single_quoted = _{ "'" ~ single_inner ~ "'" }
single_inner  = @{ (!"'" ~ ANY)* }

double_quoted = _{ "\"" ~ double_inner ~ "\"" }
double_inner  = @{ (escaped_char | normal_char)* }

escaped_char = _{ "\\" ~ ("\"" | "\\") }
normal_char  = _{ !("\\" | "\"") ~ ANY }