adnv 1.5.1

CLI that tracks, checks and auto-updates infrastructure dependency versions across Terraform, Helm, Docker, Git and npm
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91

{
  description = "adnv - tracks, checks and auto-updates infrastructure dependency versions";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    { nixpkgs, rust-overlay, ... }:
    let
      systems = [
        "x86_64-linux"
        "aarch64-linux"
        "x86_64-darwin"
        "aarch64-darwin"
      ];

      forEachSystem =
        f:
        nixpkgs.lib.genAttrs systems (
          system:
          f (
            import nixpkgs {
              inherit system;
              overlays = [ (import rust-overlay) ];
            }
          )
        );

      manifest = (nixpkgs.lib.importTOML ./Cargo.toml).package;
    in
    {
      packages = forEachSystem (pkgs: rec {
        adnv = pkgs.rustPlatform.buildRustPackage {
          pname = manifest.name;
          inherit (manifest) version;

          src = pkgs.lib.cleanSource ./.;
          cargoLock.lockFile = ./Cargo.lock;

          # cmake and perl build aws-lc-sys; git2 links a vendored libgit2 that
          # wants zlib and openssl through pkg-config.
          nativeBuildInputs = with pkgs; [
            cmake
            perl
            pkg-config
          ];
          buildInputs = with pkgs; [
            openssl
            zlib
          ];

          # The suite reaches for the network and for a writable HOME.
          doCheck = false;

          meta = {
            inherit (manifest) description;
            homepage = manifest.repository;
            license = pkgs.lib.licenses.agpl3Only;
            mainProgram = manifest.name;
          };
        };

        default = adnv;
      });

      devShells = forEachSystem (pkgs: {
        default = pkgs.mkShell {
          # Same toolchain as CI: rust-toolchain.toml is the single source.
          packages =
            [ (pkgs.rust-bin.fromRustupToolchainFile ./rust-toolchain.toml) ]
            ++ (with pkgs; [
              cargo-llvm-cov
              cmake
              convco
              glab
              openssl
              perl
              pkg-config
              zlib
            ]);
        };
      });

      formatter = forEachSystem (pkgs: pkgs.nixfmt-rfc-style);
    };
}