aaa 2.0.1

Swiss Army knife for animated ascii art
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104

# Usage:
#   nix profile add github:asciimoth/aaa
#   nix profile remove aaa
#   nix shell github:asciimoth/aaa
# Update: nix flake update
{
  description = "aaa";
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-25.11";
    flake-utils.url = "github:numtide/flake-utils";
    pre-commit-hooks.url = "github:cachix/pre-commit-hooks.nix";
    naersk = {
      url = "github:nix-community/naersk";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };
  outputs = {
    self,
    nixpkgs,
    flake-utils,
    pre-commit-hooks,
    naersk,
    ...
  }:
    flake-utils.lib.eachDefaultSystem (system: let
      pkgs = import nixpkgs {
        inherit system;
      };
      naersk' = pkgs.callPackage naersk {};

      checks = {
        pre-commit-check = pre-commit-hooks.lib.${system}.run {
          src = ./.;
          hooks = {
            cargo-check.enable = true;
            commitizen.enable = true;
            typos.enable = true;
            typos-commit = {
              enable = true;
              description = "Find typos in commit message";
              entry = let script = pkgs.writeShellScript "typos-commit" ''
                typos "$1"
              ''; in builtins.toString script;
              stages = [ "commit-msg" ];
            };
            cargo-test = {
              enable = true;
              name = "cargo test (workspace)";
              entry = "cargo test --workspace --all-features";
              pass_filenames = false;
              stages = [ "pre-commit" ];
            };
          };
        };
      };

      app = naersk'.buildPackage {
        src = ./.;
        postInstall = ''
          mkdir -p $out/share/applications $out/share/mime/packages
          cp ${./aaa.desktop} $out/share/applications/aaa.desktop
          cp ${./mime.xml} $out/share/mime/packages/3a-mime.xml

          mkdir -p $out/share/bash-completion/completions
          $out/bin/aaa completions bash > $out/share/bash-completion/completions/aaa
          mkdir -p $out/share/fish/vendor_completions.d
          $out/bin/aaa completions fish > $out/share/fish/vendor_completions.d/aaa.fish
          mkdir -p $out/share/zsh/site-functions/
          $out/bin/aaa completions zsh > $out/share/zsh/site-functions/_aaa
          mkdir -p $out/share/nu/completions
          $out/bin/aaa completions nush > $out/share/nu/completions/aaa.nu
        '';
      };
    in {
      devShells.default = pkgs.mkShell {
        inherit (checks.pre-commit-check) shellHook;
        buildInputs = with pkgs; [
          # app

          cargo
          # clippy
          cargo-cross
          cargo-zigbuild
          zig
          goreleaser

          typos
          commitizen

          lolcat

          neofetch
          fastfetch
          screenfetch
          nitch
          profetch
          leaf
          fetch-scm
        ];
      };

      packages.default = app;
    });
}