[−][src]Crate rdftk_iri

Another implementation of the IRI and URI specifications. It provides an IRI type that supports the semantics of the IRI, URI, URL, and URN specifications.

Example

TBD

Specifications

RFC-1630 Universal Resource Identifiers in WWW: A Unifying Syntax for the Expression of Names and Addresses of Objects on the Network as used in the World-Wide Web
RFC-1736 Functional Recommendations for Internet Resource Locators
RFC-1737 Functional Requirements for Uniform Resource Names
RFC-1738 Uniform Resource Locators (URL)
RFC-1808 Relative Uniform Resource Locators
RFC-2141 URN Syntax
RFC-2396 Uniform Resource Identifiers (URI): Generic Syntax
RFC-2616 Hypertext Transfer Protocol -- HTTP/1.1; §3.2 Uniform Resource Identifiers
RFC-2717 Registration Procedures for URL Scheme Names
RFC-2732 Format for Literal IPv6 Addresses in URL's
RFC-3305 Report from the Joint W3C/IETF URI Planning Interest Group: Uniform Resource Identifiers (URIs), URLs, and Uniform Resource Names (URNs): Clarifications and Recommendations
RFC-3987 Internationalized Resource Identifiers (IRIs)
RFC-6963 A Uniform Resource Name (URN) Namespace for Examples
RFC-8141 Uniform Resource Names (URNs)

From RFC-2396, appendix A. Collected BNF for URI:

URI-reference = [ absoluteURI | relativeURI ] [ "#" fragment ]
absoluteURI   = scheme ":" ( hier_part | opaque_part )
relativeURI   = ( net_path | abs_path | rel_path ) [ "?" query ]

hier_part     = ( net_path | abs_path ) [ "?" query ]
opaque_part   = uric_no_slash *uric

uric_no_slash = unreserved | escaped | ";" | "?" | ":" | "@" |
                "&" | "=" | "+" | "$" | ","

net_path      = "//" authority [ abs_path ]
abs_path      = "/"  path_segments
rel_path      = rel_segment [ abs_path ]

rel_segment   = 1*( unreserved | escaped |
                    ";" | "@" | "&" | "=" | "+" | "$" | "," )

scheme        = alpha *( alpha | digit | "+" | "-" | "." )

authority     = server | reg_name

reg_name      = 1*( unreserved | escaped | "$" | "," |
                    ";" | ":" | "@" | "&" | "=" | "+" )

server        = [ [ userinfo "@" ] hostport ]
userinfo      = *( unreserved | escaped |
                   ";" | ":" | "&" | "=" | "+" | "$" | "," )

hostport      = host [ ":" port ]
host          = hostname | IPv4address
hostname      = *( domainlabel "." ) toplabel [ "." ]
domainlabel   = alphanum | alphanum *( alphanum | "-" ) alphanum
toplabel      = alpha | alpha *( alphanum | "-" ) alphanum
IPv4address   = 1*digit "." 1*digit "." 1*digit "." 1*digit
port          = *digit

path          = [ abs_path | opaque_part ]
path_segments = segment *( "/" segment )
segment       = *pchar *( ";" param )
param         = *pchar
pchar         = unreserved | escaped |
                ":" | "@" | "&" | "=" | "+" | "$" | ","

query         = *uric

fragment      = *uric
uric          = reserved | unreserved | escaped
reserved      = ";" | "/" | "?" | ":" | "@" | "&" | "=" | "+" |
                "$" | ","
unreserved    = alphanum | mark
mark          = "-" | "_" | "." | "!" | "~" | "*" | "'" |
                "(" | ")"

escaped       = "%" hex hex
hex           = digit | "A" | "B" | "C" | "D" | "E" | "F" |
                        "a" | "b" | "c" | "d" | "e" | "f"

alphanum      = alpha | digit
alpha         = lowalpha | upalpha

lowalpha = "a" | "b" | "c" | "d" | "e" | "f" | "g" | "h" | "i" |
           "j" | "k" | "l" | "m" | "n" | "o" | "p" | "q" | "r" |
           "s" | "t" | "u" | "v" | "w" | "x" | "y" | "z"
upalpha  = "A" | "B" | "C" | "D" | "E" | "F" | "G" | "H" | "I" |
           "J" | "K" | "L" | "M" | "N" | "O" | "P" | "Q" | "R" |
           "S" | "T" | "U" | "V" | "W" | "X" | "Y" | "Z"
digit    = "0" | "1" | "2" | "3" | "4" | "5" | "6" | "7" |
           "8" | "9"

Also, Excluded US-ASCII Characters:

control  = <US-ASCII coded characters 00-1F and 7F hexadecimal>
space    = <US-ASCII coded character 20 hexadecimal>
delims   = "<" | ">" | "#" | "%" | <">
unwise   = "{" | "}" | "|" | "\" | "^" | "[" | "]" | "`"

To support IPv6 addresses the following changes were made in RFC-2732:

The following changes to the syntax in RFC 2396 are made:
(1) change the 'host' non-terminal to add an IPv6 option:

   host          = hostname | IPv4address | IPv6reference
   ipv6reference = "[" IPv6address "]"

where IPv6address is defined as in RFC2373 [ARCH].

(2) Replace the definition of 'IPv4address' with that of RFC 2373, as
it correctly defines an IPv4address as consisting of at most three
decimal digits per segment.

(3) Add "[" and "]" to the set of 'reserved' characters:

   reserved    = ";" | "/" | "?" | ":" | "@" | "&" | "=" | "+" |
                 "$" | "," | "[" | "]"

and remove them from the 'unwise' set:

   unwise      = "{" | "}" | "|" | "\" | "^" | "`"

Re-exports

pub use scheme::KnownSchemes;

pub use scheme::Scheme;

pub use authority::Authority;

pub use authority::Host;

pub use authority::KnownPorts;

pub use authority::Port;

pub use path::Path;

pub use query::Query;

pub use query::QueryPart;

pub use fragment::Fragment;

pub use iri::IRI;

Modules

authority	Provides the `Authoriy` component of an `IRI` comprising `Host`, `Port`, and `KnownPorts` types.
builder	Provides a builder experience for creating `IRI` instances.
error	Provides the `IRI` specific `Error` and `Result` types.
fragment	Provides the `Fragment` component of an `IRI`.
iri	The overall `IRI` type comprised of a `Scheme`, `Authority`, `Path`, `Query`, and `Fragment`.
path	Provides the `Path` component of an `IRI`.
query	Provides the `Query` component of an `IRI`.
scheme	Provides the `Scheme` component of an `IRI` as well as a set of known schemes in the `KnownSchemes` enum.

Traits

Normalize