smux-cli 0.1.10

Small Rust CLI for tmux session selection and creation
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77

{
  description = "smux development environment";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
    flake-utils.url = "github:numtide/flake-utils";
    rust-overlay.url = "github:oxalica/rust-overlay";
  };

  outputs =
    {
      self,
      nixpkgs,
      flake-utils,
      rust-overlay,
    }:
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        cargoToml = builtins.fromTOML (builtins.readFile ./Cargo.toml);
        pkgs = import nixpkgs {
          inherit system;
          overlays = [ (import rust-overlay) ];
        };
        rustToolchain = pkgs.rust-bin.stable.latest.default.override {
          extensions = [
            "clippy"
            "rust-analyzer"
            "rust-src"
            "rustfmt"
          ];
        };
        rustPlatform = pkgs.makeRustPlatform {
          cargo = rustToolchain;
          rustc = rustToolchain;
        };
      in
      {
        packages.smux = rustPlatform.buildRustPackage {
          pname = "smux";
          version = cargoToml.package.version;
          src = ./.;
          cargoLock.lockFile = ./Cargo.lock;
          nativeBuildInputs = [ pkgs.installShellFiles ];

          postInstall = ''
            tmpdir="$(mktemp -d)"
            "$out/bin/smux" completions zsh --dir "$tmpdir/completions"
            "$out/bin/smux" man --dir "$tmpdir/man"
            installShellCompletion --zsh "$tmpdir/completions/_smux"
            installManPage "$tmpdir"/man/*.1 "$tmpdir"/man/*.5
          '';

          meta = with pkgs.lib; {
            description = "Small Rust CLI for tmux session selection and creation";
            mainProgram = "smux";
            platforms = platforms.unix;
          };
        };

        packages.default = self.packages.${system}.smux;
        apps.default = flake-utils.lib.mkApp {
          drv = self.packages.${system}.smux;
        };

        devShells.default = pkgs.mkShell {
          packages = with pkgs; [
            rustToolchain
            pkg-config
            tmux
            fzf
            zoxide
          ];
        };
      }
    );
}